plugins {
    java
    id("com.gradleup.shadow") version "8.3.0"
}

group = "party.cybsec"
version = "1.0.0-SNAPSHOT"

repositories {
    mavenCentral()
    maven("https://repo.papermc.io/repository/maven-public/")

}

dependencies {
    // paper api
    compileOnly("io.papermc.paper:paper-api:1.21.11-R0.1-SNAPSHOT")
    
    // sqlite
    implementation("org.xerial:sqlite-jdbc:3.47.1.0")
    
    // jda discord bot
    implementation("net.dv8tion:JDA:6.3.0") {
        exclude(module = "opus-java")
    }


}

java {
    toolchain.languageVersion.set(JavaLanguageVersion.of(21))
}

tasks {
    shadowJar {
        archiveClassifier.set("")
        
        // relocate dependencies to avoid conflicts
        relocate("org.xerial", "party.cybsec.oyetickets.libs.xerial")
    }
    
    jar {
        archiveClassifier.set("slim")
    }
    
    build {
        dependsOn(shadowJar)
    }
    
    processResources {
        val props = mapOf("version" to version)
        inputs.properties(props)
        filteringCharset = "UTF-8"
        filesMatching("plugin.yml") {
            expand(props)
        }
    }
}